Organic solar cell (with Nanoscale Layers and Films)

silvaco code:-

go atlas

#

mesh auto

x.mesh Loc=0 Spacing=1

x.mesh Loc=1 Spacing=1

y.mesh Loc=0 Spacing=0.1

y.mesh Loc=0.47 Spacing=0.1

#

region num=1 x.min=0 x.max=1 y.min=0 y.max=0.2 material=ITO

region num=2 x.min=0 x.max=1 y.min=0.20 y.max=0.27 material=ZnO

region num=3 x.min=0 x.max=1 y.min=0.27 y.max=0.37 user.material=P3HT

region num=4 x.min=0 x.max=1 y.min=0.37 y.max=0.47 material=silver

#

electrode num=1 name=cathode x.min=0 x.max=1 y.min=0 y.max=0

electrode num=2 name=anode x.min=0 x.max=1 y.min=0.47 y.max=0.47

#

Material name=P3HT Eg300=1.95 Nc300=2e21 Nv300=2e21 Permittivity=3 Affinity=3.2 Mun=1e-6 Mup=1.2e-3 \

taun0=1e-6 taup0=1e-7 USER.GROUP=semiconductor USER.DEFAULT=silicon sopra=P3HT.nk

material material=ITO sopra=Ito2.nk

material material=silver sopra=Ag.nk

#

doping uniform conc=1E15 p.type reg=3

doping uniform conc=1E21 n.type reg=2

#

Contact name=cathode Workfun=4.3

Contact name=anode Workfun=4.7

#

save outf=p3ht.str

tonyplot p3ht.str

go atlas

mesh infile = p3ht.str

#

models conmob fldmob srh optr print

method newton trap maxtrap=10

output con.band val.band band.par e.mobility e.velocity

beam num=1 am1.5 x.o=.5 y.o=-1 angle=90 wavel.start=0.305 wavel.end=3.455 wavel.num=100 \

power.file=C:/sedatools/examples/solar/solarex09.spec

#

solve init

solve prev

solve b1=1

log outf=mie.log

solve name=anode vanode=0 vstep=0.01 vfinal=0.9

log off

tonyplot mie.log

#

extract init infile="mie.log"

extract name="IV" curve(v."Anode",i."Cathode") outfile="curveIV.dat"

#

extract name="Jsc" y.val from curve(v."Anode", i."Cathode") where x.val=0

extract name="Voc" x.val from curve(v."Anode", i."Cathode") where y.val=0

extract name="Pm" max(curve(v."Anode",(v."Anode"* i."Cathode")))

extract name="Vm" x.val from curve(v."Anode",(v."Anode"* i."Cathode")) \

where y.val=$"Pm"

extract name="Im" $"Pm"/$"Vm"

extract name="FF" $"Pm"/($"Jsc"*$"Voc")

tonyplot curveIV.dat

Quit

result:-

if you need p3ht  then i will write below and save it as P3HT.nk file

12

0.25024 1.55318 0.25475

0.33525 1.48282 0.33525

0.41156 1.23235 0.43828

0.50558 1.72542 0.50558

0.56804 2.24214 0.56354

0.59058 2.17122 0.59509

0.60829 2.1791 0.63083

0.75609 1.8425 0.87265

1.00241 1.75638 1.09192

1.25324 1.7333 1.42325

1.49505 1.71754 1.4268